3 HGR : TEXT : HOME : INPUT "DO YOU HAVE A RAMCARD? ";R$:RAM = 48: IF LEFT$ (R$,1) = "Y" THEN RAM = 64

5 PRINT CHR$ (4)"BLOAD GREY16-"RAM"K"

10 NRM = 4096:FULL = 4099:GY = 4102

11 POKE 10,76: POKE 11,0: POKE 12,134

12 REM SETUP EPSON CALL

13 PRINT CHR$ (4)"BLOAD EPRINT,A$8600"

20 CAM = NRM

30 SOAK = 256:LO = 128:HI = 384

40 INC = (HI - LO) / 15

50 SL = 768:SH = 769:ST = 770:SP = 771:KEY = 772:KP = 773:EI = 774

60 HOME : INPUT "ENTER VISICAM SLOT: ";SN: IF SN < 1 OR SN > 7 THEN 60

70 POKE ST,SN * 16: REM "SLOTNUMBER

75 POKE SP,0: REM "SCREENPOSITION

80 POKE SH, INT (SOAK / 256): POKE SL,SOAK - INT (SOAK / 256) * 256: REM "SOAKTIME

90 HOME : VTAB 21: PRINT TAB( 11);"CURRENT EXP: "SOAK" MS ": PRINT : PRINT "LO EXP: ";LO;" MS "; TAB( 24);"HI EXP: ";HI;" MS "

100 CALL CAM

110 IF NOT ( PEEK (KP)) THEN 100

120 KEY$ = CHR$ ( PEEK (KEY) - 128)

125 IF KEY$ = "E" THEN 500

130 IF KEY$ = "Q" THEN TEXT : HOME : END

140 IF KEY$ = "N" THEN CAM = NRM: HGR

150 IF KEY$ = "F" THEN CAM = FULL: HGR

160 IF KEY$ = "G" THEN GOSUB 400

170 IF KEY$ = "S" THEN GOSUB 1000

175 IF KEY$ = "L" THEN GOSUB 2000

177 IF KEY$ = "P" THEN X = USR (256 * 32 + 128)

180 GOTO 80

400 HOME : VTAB 22: PRINT "COUNTDOWN: ";

410 POKE SL,LO - INT (LO / 256) * 256: POKE SH, INT (LO / 256): POKE EI,INC

420 CALL GY

430 HOME : VTAB 22: PRINT "HIT 'S' TO SAVE,": PRINT " ANY OTHER KEY TO CONTINUE.": GET KEY$

440 RETURN

500 HOME : VTAB 22: PRINT "CHANGE CURRENT, LO, OR": INPUT " HI EXPOSURE? (C,L,H): ";CH$

505 IF CH$ = "" THEN 80

510 IF CH$ < > "C" THEN 540

520 INPUT "ENTER NEW CURRENT: ";NE$: IF NE$ = "" THEN 590

525 NE = VAL (NE$): IF NE < 1 OR NE > 8000 THEN 520

530 SOAK = NE: GOTO 590

540 IF CH$ < > "L" THEN 570

550 INPUT "ENTER NEW LO: ";NE$: IF NE$ = "" THEN 590

555 NE = VAL (NE$): IF NE < 1 OR NE > 8000 OR NE > HI THEN 550

560 LO = NE: GOTO 590

570 IF CH$ < > "H" THEN 500

580 INPUT "ENTER NEW HI: ";NE$: IF NE$ = "" THEN 590

585 NE = VAL (NE$): IF NE < 1 OR NE > 8000 OR NE < LO THEN 580

588 HI = NE

590 INC = (HI - LO) / 15

595 GOTO 80

1000 HOME : VTAB 22: PRINT "ENTER A NAME FOR": INPUT "THE PICTURE: ";NA$

1010 IF LEN (NA$) < = 0 THEN RETURN

1020 PRINT CHR$ (4)"BSAVE "NA$",A$2000,L$2000"

1030 HOME : RETURN

2000 HOME : VTAB 22: PRINT "ENTER A NAME FOR": INPUT "THE PICTURE: ";NA$

2010 IF LEN (NA$) < = 0 THEN RETURN

2020 PRINT CHR$ (4)"BLOAD "NA$

2025 GET KEY$

2030 HOME : RETURN